I2S Output of 4 Channels with an ESP32

Recently there was a discussion on how to output more then 2 channels via I2S. I2S is limited to 2 channels, but the ESP32 has 2 I2S ports, so we can output a maximum of 4 channels!

Arduino Sketch

I have added a small example that shows how this can be done using my AudioTools library:

#include <SPI.h>
#include <SD.h>
#include "AudioTools.h"
#include "AudioCodecs/CodecMP3Helix.h"

const int chipSelect=10;
AudioInfo info(44100, 2, 16);
I2SStream i2s_1; // final output
I2SStream i2s_2; // final out
ChannelsSelectOutput out;
WAVDecoder wav;
EncodedAudioOutput decoder(&out, &wav); // Decoding stream
StreamCopy copier; 
File audioFile;

void setup(){
  Serial.begin(115200);
  AudioLogger::instance().begin(Serial, AudioLogger::Info);  

  // setup file
  SD.begin(chipSelect);
  audioFile = SD.open("/Music/ch4.wav");

  // setup i2s
  auto config1 = i2s_1.defaultConfig(TX_MODE);
  config1.copyFrom(info);
  config1.port_no = 0;
  i2s_1.begin(config1);
  auto config2 = i2s_2.defaultConfig(TX_MODE);
  config2.copyFrom(info);
  config2.port_no = 1;
  i2s_2.begin(config2);

  // split channels to different i2s ports
  out.addOutput(i2s_1, 0, 1);
  out.addOutput(i2s_2, 2, 3);
  //out.addNotifyAudioChange(i2s_1);
  //out.addNotifyAudioChange(i2s_2);
  out.begin(info);

  // setup decoder
  decoder.begin();

  // begin copy
  copier.begin(decoder, audioFile);
}

void loop(){
  if (!copier.copy()) {
    stop();
  }
}

We define 2 separate I2SStream audio sink objects. The data source is a decoded WAV file that has audio with 4 channels and we just need to use a ChannelsSelectOutput as additional intermediary sink. This allows us to define which channels should go to which final output. In the example channel 0 and 1 go to the I2S on port 0 and the channels 2 and 3 go to port 1.

Please note that these output destinations are not automatically notified about format changes, so if you want this to happen, you need to add the corresponding addNotifyAudioChange() statements yourself.

This API might be changing, so please check the potentially updated example on Github!