Using the AI Thinker Audio Kit Buttons

As you might know from my last posts I am currently extending my Arduino Audio Tools library to support the AI Thinker Audio Kit which is based on the ES8388 audio chip.
.

Originally I was of the opinion that the program logic for reading of the GPIO pins and the processing of the related actions should belong into a specific Arduino sketch and should not be part of an Audio Framework.

The Audio Kit made me revise this because I think that an Arduino Sketch should be as concise as possible. Therefore I have created the AudioActions class that has been integrated into the AudioKit.

Since the Audio Kit does not have any display, I think to use TTS is a good choice to feed back information to the user.

Here is the example:

Arduino Sketch

#include "flite_arduino.h"
#include "AudioTools.h"
#include "AudioDevices/ESP32AudioKit/AudioKit.h"

using namespace audio_tools;

AudioKitStream kit;
Flite flite(kit);

void button1(){
  flite.say("Button One");  
}
void button2(){
  flite.say("Button Two");  
}
void button3(){
  flite.say("Button Three");  
}
void button4(){
  flite.say("Button Four");  
}

// Arduino setup
void setup(){
  Serial.begin(115200);

  auto cfg = kit.defaultConfig();
  cfg.bits_per_sample = 16;
  cfg.channels = 1;
  cfg.sample_rate = 8000;
  kit.begin(cfg);

  // Assign pins to methods
  kit.addAction(PIN_KEY1, button1);
  kit.addAction(PIN_KEY2, button2);
  kit.addAction(PIN_KEY3, button3);
  kit.addAction(PIN_KEY4, button4);

  // example with actions using lambda expression
  auto down = []() { flite.say("Volume down"); kit.volumeDown(); };
  kit.addAction(PIN_KEY5, down);
  auto up = []() { flite.say("Volume up"); kit.volumeUp();  };
  kit.addAction(PIN_KEY6, up);

  // we are ready to process actions now
  flite.say("The application has started. Please push a button to select the function");

}

// Arduino Loop
void loop() {
  kit.processActions();
}

You just need to define you handler methods (button1, button2…) and assign them to the GPIO pins. The PIN_KEY5 and PIN_KEY6 have been predefined in the AudioKitStream to handle the volume. But you can overwrite this with your own methods – as demonstrated in the sketch.

I think it could not be easier then this!

Source Code

The source code for this example can also be found on Github. Please note that this example was working at the time of publishing. If you want to try it out please use this (potentially updated) example.

Dependencies

You need to install the following libraries:

• FLITE
• Arduino Audio Tolls
• AudioKit

Final Comments

I was quite happy with the AudioKit so far, but after some more trials I noted that the Kit has quite some design bugs: One of them is that there are pin conflicts: When the SD card is activated the key 1 and key 2 do not work any more!