Back to Basics – A simple ESP32 sound generator (tone)

The first thing I wanted to try out after I have received my Piezo Buzzer was to generate some simple beeps. In Standard Arduino there exists the tone() function which – unfortunately – is not available in the ESP32 Arduino implementation.

There are libraries to bridge this gap, but I was wondering how this could be implemented using the functionality which is available. I came up with the following alternatives:

• Use I2S together with the built in DAC: This is not simple and in the best case we can generate sounds on max 2 pins.
• Use the built in PWM functionality: The functionality is available to set the frequency and the number of pins are limited by the available timer (2 channels groups * 8 channels each) which gives 16 parallel sounds which is not bad.
• Use digital output together with a timer: There are 2 groups where each has 2 general purpose timers.

Here is an first simple example which uses the last approach. We use a timer which toggels the indicated digital pin on and off in the indicated frequency. This is done in a timer interrupt using an alarm.

const int PIN = 25;

hw_timer_t* timer = NULL;
bool value = true;
int frequency = 20; // 20 to 20000

void IRAM_ATTR onTimer() {
  value = !value;
  digitalWrite(PIN, value); 
}

void setup() {
    Serial.begin(115200);
    pinMode(PIN, OUTPUT);    // sets the digital pin as output
    setupTimer();
}

void setupTimer() {
    // Use 1st timer of 4  - 1 tick take 1/(80MHZ/80) = 1us so we set divider 80 and count up 
    timer = timerBegin(0, 80, true);//div 80
    timerAttachInterrupt(timer, &onTimer, true);
}

void setFrequency(long frequencyHz){
    timerAlarmDisable(timer);
    timerAlarmWrite(timer, 1000000l / frequencyHz, true);
    timerAlarmEnable(timer);
}

void tone(long frequencyHz, long durationMs){
    setFrequency(frequencyHz);
    delay(durationMs);
}

void loop() {
    Serial.print(frequency); // in hz
    Serial.println(" hz");
    tone(frequency,1000);
    frequency+=100;
    if (frequency>=200000){
      frequency = 20;
    }
}

I decided to use this approach and change it so, that we can drive any number of pins with one single timer.